Android Studio – Unable to pair device for debugging over Wi-Fi, Android Studio (Bumblebee)

Sometimes this is the most finicky thing. I’ve had GUI connections break mid-session for no apparent reason.

I wrote a .bat that I hope other people find useful.

1. It asks for ip.
   • It may ask for ip details.
2. It then asks for the CONNECTION PORT (used in the final command, but not visible when the prompt is up.
3. It then asks for the PAIRING CODE.
4. It then asks for the PAIRING PORT.

Here’s the code

@echo off
setlocal enabledelayedexpansion

:start

set useIP=
rem Step 1: Choose IP
echo Menu:
echo    0: Custom IP
  if not exist batconfig.txt (
    echo    1: NO PREVIOUS IP CONFIGURED
  ) else (
    set /p lastIP=<batconfig.txt
    echo    1. Last IP: !lastIP!
  )
echo    2: 10.0.0.---
echo    3: 192.168.1.---
set /p ipOption=Select Option: 

if %ipOption%==0 (
  set /p customIP=Enter custom IP: 
  set useIP=!customIP!
) else if %ipOption%==1 (
  if not exist batconfig.txt (
    echo batconfig.txt not found.
    pause
    goto start
  ) else (
    set /p useIP=<batconfig.txt
    echo Loaded IP: !useIP!
  )
) else if %ipOption%==2 (
  set /p ipPrompt=Enter last segment of IP 10.0.0.---: 
  set useIP=10.0.0.!ipPrompt!
  echo %useIP%
) else if %ipOption%==3 (
  set /p ipPrompt=Enter last segment of IP 192.168.1.---: 
  set useIP=192.168.1.!ipPrompt!
) else (
  echo Invalid selection. Restarting...
  goto start
)

rem Step 2: Connection Port
set /p connectPort=Enter CONNECTION PORT (main screen) for %useIP%: 

rem Step 3: Pairing Code and Port
set /p pairingCode=Enter PAIRING CODE (popup) for %useIP%: 
set /p pairingPort=Enter PAIRING PORT (popup) for %useIP%: 
echo Attempting to connect to %useIP%:!pairingPort!

rem Step 4: Run adb pair command
set error=
echo Executing command... adb pair %useIP%:!pairingPort! !pairingCode!
adb pair %useIP%:!pairingPort! !pairingCode! >error.txt
set error=!errorlevel!
if !error! equ 0 (
  echo Successfully paired with %useIP%:%pairingPort%
  echo %useIP%>batconfig.txt

  echo Executing command... adb connect %useIP%:%connectPort%
  adb connect %useIP%:%connectPort%
) else (
  rem Step 4: Output error message
  set /p error=<error.txt
  echo !error!
)

Sometimes ADB is extra-fussy and I have to disconnect my phone from WIFI, reconnect it, and re-enable wireless debugging.